home *** CD-ROM | disk | FTP | other *** search
/ Turnbull China Bikeride / Turnbull China Bikeride - Disc 2.iso / STUTTGART / GRAPHICS / RAYTRACING / POVRAY3 / POV301 / povray3 / docsdemo / pov / blobdem4 < prev    next >
Text File  |  1997-01-21  |  2KB  |  62 lines
  1. //
  2. // POV-Ray(tm) 3.0 tutorial example scene.
  3. // Copyright 1996 by the POV-Ray Team
  4. //
  5.  
  6. #include "colors.inc"
  7.  
  8. camera { 
  9.   angle 20
  10.   location<0,2,-10>
  11.   look_at<0,0,0>
  12. }
  13.  
  14. light_source { <10, 20, -10> color White }
  15.  
  16. blob {
  17.   threshold .65
  18.  
  19.   sphere { <-.23,-.32,0>,.43, 1 scale <1.95,1.05,.8> }   //palm
  20.   sphere { <+.12,-.41,0>,.43, 1 scale <1.95,1.075,.8> }  //palm
  21.   sphere { <-.23,-.63,0>, .45, .75 scale <1.78, 1.3,1> } //midhand
  22.   sphere { <+.19,-.63,0>, .45, .75 scale <1.78, 1.3,1> } //midhand
  23.   sphere { <-.22,-.73,0>, .45, .85 scale <1.4, 1.25,1> } //heel
  24.   sphere { <+.19,-.73,0>, .45, .85 scale <1.4, 1.25,1> } //heel
  25.                                                              
  26.   cylinder { <-.65,-.28,0>, <-.65,.28,-.05>, .26, 1 }    //lower pinky
  27.   cylinder { <-.65,.28,-.05>, <-.65, .68,-.2>, .26, 1 }  //upper pinky
  28.   
  29.   cylinder { <-.3,-.28,0>, <-.3,.44,-.05>, .26, 1 }      //lower ring
  30.   cylinder { <-.3,.44,-.05>, <-.3, .9,-.2>, .26, 1 }     //upper ring
  31.                     
  32.   cylinder { <.05,-.28,0>, <.05, .49,-.05>, .26, 1 }     //lower middle
  33.   cylinder { <.05,.49,-.05>, <.05, .95,-.2>, .26, 1 }    //upper middle
  34.  
  35.   cylinder { <.4,-.4,0>, <.4, .512, -.05>, .26, 1 }      //lower index
  36.   cylinder { <.4,.512,-.05>, <.4, .85, -.2>, .26, 1 }    //upper index
  37.  
  38.   cylinder { <.41, -.95,0>, <.85, -.68, -.05>, .25, 1 }  //lower thumb
  39.   cylinder { <.85,-.68,-.05>, <1.2, -.4, -.2>, .25, 1 }  //upper thumb
  40.  
  41.   // 
  42.   // Counteract the bulges.
  43.   //
  44.  
  45.   sphere { <-.65,.28,-.05>, .26, -1 } //counteract pinky knuckle bulge
  46.   sphere { <-.65,-.28,0>, .26, -1 }   //counteract pinky palm bulge
  47.   
  48.   sphere { <-.3,.44,-.05>, .26, -1 }  //counteract ring knuckle bulge
  49.   sphere { <-.3,-.28,0>, .26, -1 }    //counteract ring palm bulge
  50.               
  51.   sphere { <.05,.49,-.05>, .26, -1 }  //counteract middle knuckle bulge
  52.   sphere { <.05,-.28,0>, .26, -1 }    //counteract middle palm bulge
  53.   
  54.   sphere { <.4,.512,-.05>, .26, -1 }  //counteract index knuckle bulge
  55.   sphere { <.4,-.4,0>, .26, -1 }      //counteract index palm bulge
  56.   
  57.   sphere { <.85,-.68,-.05>, .25, -1 } //counteract thumb knuckle bulge
  58.   sphere { <.41,-.7,0>, .25, -.89 }   //counteract thumb heel bulge
  59.   
  60.   pigment { Flesh }
  61. }
  62.